home *** CD-ROM | disk | FTP | other *** search
/ SGI Hot Mix 17 / Hot Mix 17.iso / HM17_SGI / research / lib / leefilt.pro < prev    next >
Text File  |  1997-07-08  |  4KB  |  135 lines
  1. ; $Id: leefilt.pro,v 1.3 1996/12/17 23:45:06 lubos Exp $
  2.  
  3. Function Lee_filter_exact,A,N,SIG
  4. ;
  5. ; Slow, but accurate Lee filter. Derived from
  6. ; Jong-Sen Lee, Optical Engineering 25(5), 636-643 (May 1986)
  7. ;
  8.   Z=(AA=FLOAT(A))
  9.   Delta=(T_Y=(T_X=(N-1)/2))
  10.   SZ=size(AA) & N_SAMPLES=SZ[1]
  11. ;
  12.   mean=smooth(AA,N,/EDGE_TRUNCATE) & mean2=mean^2.
  13. ;
  14.   IF SZ[0] eq 1 THEN BEGIN
  15.      FOR S=T_X,N_SAMPLES-T_X-1 DO $
  16.         Z[S]=TOTAL((AA[S-Delta:S+Delta] - mean[S])^2.)
  17.   ENDIF ELSE BEGIN
  18.      N_LINES=SZ[2]
  19. ;
  20. ; Compute Variance of Z
  21. ;
  22.     FOR L=T_Y, N_LINES-T_Y-1 DO $
  23.       FOR S=T_X,N_SAMPLES-T_X-1 DO $
  24.         Z[S,L]=TOTAL((AA[S-Delta:S+Delta,L-Delta:L+Delta] - mean[S,L])^2.)
  25.   ENDELSE
  26. ;
  27. ; Upon starting the next equation,  Z = Var(Z). Upon exit, Z = Var(X) 
  28. ; of equation 19 of Lee, Optical Engineering 25(5), 636-643 (May 1986)
  29. ;
  30. ; VAR_X = (VAR_Z + Mean^2 )/(Sigma^2 +1) - Mean^2   (19)
  31. ;
  32.   Z=( (TEMPORARY(Z) +mean2) /(1+Sig^2.)) - mean2 
  33. ;
  34. ; return value from equation 21,22 of Lee, 1986.
  35. ; K = ( VAR_X/(mean^2 * Sigma^2 + VAR_X) )          (22)
  36. ; Filtered_Image = Mean + K * ( Input_Image - Mean) (21)
  37. ; 
  38.   return, mean + (AA-mean) * ( Z/(mean2*Sig^2. + Z) ) 
  39. END
  40.  
  41. Function Lee_filter_fast,A,N,SIG
  42. ; Faster, but less accurate Lee filter
  43. ; Only recomended when N < 7
  44. ;
  45.   AA=FLOAT(A)
  46. ;
  47.   mean=SMOOTH(AA,N,/EDGE_TRUNCATE) & mean2=mean^2. 
  48.   AA=AA-mean
  49. ;
  50.  VAR_X=((SMOOTH(AA^2.,N,/EDGE_TRUNCATE)+mean2)/(1.+Sig^2.)) - mean2
  51. ;
  52. ; return value from equation 21,22 of Lee, 1986.
  53. ; K = ( VAR_X/(mean^2 * Sigma^2 + VAR_X) )          (22)
  54. ; Filtered_Image = Mean + K * ( Input_Image - Mean) (21)
  55. ; 
  56.  RETURN, mean + AA * (VAR_X / ( mean2 * Sig^2. + VAR_X))
  57. ;
  58. END
  59.  
  60. Function Leefilt, A, N, Sig,EXACT=EXACT
  61. ;+
  62. ; NAME:
  63. ;    LEEFILT
  64. ;
  65. ; PURPOSE:
  66. ;    Performs the Lee filter algorithm on an image array using a 
  67. ;    box of size 2N+1.  This function can also be used on vectors.
  68. ;
  69. ; CATEGORY:
  70. ;    E3 Smoothing (image).
  71. ;
  72. ; CALLING SEQUENCE:
  73. ;    Result = LEEFILT(A [, N, Sig])
  74. ;
  75. ; INPUTS:
  76. ;    A:    The input image array or one-dimensional vector.
  77. ;
  78. ; OPTIONAL INPUT PARAMETERS:
  79. ;    N:    The size of the filter box is 2N+1.  The default value is 5.
  80. ;
  81. ;    Sig:    Estimate of the standard deviation.  The default is 5.
  82. ;        If Sig is negative the procedure requests a value to be 
  83. ;        entered, and displays the resulting image or vector.  This 
  84. ;               cycle continues until a zero value of Sig is entered.
  85. ;
  86. ; KEYWORDS:
  87. ;    EXACT:  Use this keyword to use a more accurate, but much slower
  88. ;        Lee filter algorithm. Recommended when N > ~7.
  89. ; OUTPUTS:
  90. ;    The filtered image or vector is returned.
  91. ;
  92. ; COMMON BLOCKS:
  93. ;    None.
  94. ;
  95. ; SIDE EFFECTS:
  96. ;    Displays the filtered image in an IDL window using TVSCL or PLOT if 
  97. ;       Sig is negative.
  98. ;
  99. ; RESTRICTIONS:
  100. ;    None.
  101. ;
  102. ; PROCEDURE:
  103. ;    The LEE (Optical Engineering, Vol 25, No 5, Pg 636-643, May 1986) 
  104. ;       technique smooths additive image noise by generating statistics in
  105. ;       a local neighborhood and comparing them to the expected values.
  106. ;
  107. ; MODIFICATION HISTORY:
  108. ;    Written, 24-Nov-1982, by R. A. Howard, Naval Research Lab,
  109. ;                 Washington, DC 20375
  110. ;       Modified, 30-May-1996, SVP. Modifed to match 1986 algorithm &
  111. ;                              Added /EXACT at user suggestion.
  112. ;                              Added PLOT for vector support.
  113. ;-
  114. ;
  115. ON_ERROR,2                      ;Return to caller if an error occurs
  116. NP = N_params(0)
  117. IF np lt 3 THEN Sig = 5. else Sig=FLOAT(Sig)    ;supply defaults
  118. IF np lt 2 THEN n = 5
  119. pl = sig LE 0.            ;true if interactive mode
  120. loop:
  121.     IF pl THEN read,'Type in Sigma (0 to quit) :  ',sig
  122.     IF sig EQ 0 THEN goto,endp
  123.         IF keyword_set(EXACT) THEN $
  124.            f=lee_filter_exact(a,2*n+1,Sig)  ELSE $
  125.        f=lee_filter_fast(a,2*n+1,Sig) 
  126.     IF pl THEN BEGIN
  127.            IF (size(f))[0] eq 1 then $
  128.            PLOT,f,xtitle='Element of A',ytitle='Value of A',$
  129.                 title='Lee Filtered A, N ='+string(N,FORMAT='(I3)')+', Sigma = '+$
  130.                 string(Sig,FORMAT='(F5.2)') else TVSCL,f
  131.        GOTO , loop
  132.     ENDIF
  133. endp:    RETURN,f
  134. END
  135.